/*
 * 7 Segment 4 Digits clock with digit point separator
 *
 * It uses display module with common anode and DS1307 RTC module to enhance
 * time keeping ability of Atmega 328p based Arduino Nano microcontroller and
 * 2 buttons for adjusting time.
 */

/* This software distributed under BSD 2 Clause License
 *
 * Copyright (c) Sergei Fedosoff, All rights reserved.
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 *
 * Redistributions of source code must retain the above copyright
 * notice, this listof conditions and the following disclaimer.
 * Redistributions in binary form must reproduce the above copyright
 * notice, this list of conditions and the following disclaimer in the
 * documentation and/or other materials provided with the distribution.
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
 * A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
 * HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
 * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED
 * TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
 * PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
 * LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
 * NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
 * SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITYOF SUCH DAMAGE.
 */

/* DS1307 lib by FrankieChu for Seeed RTC module, in my case
 * Grove___RTC_DS1307-1.0.0.zip */
#include <DS1307.h>
#include <SevSeg.h>

DS1307 clock;
SevSeg Display;

/* push button stuff */
const long initial_delay = 600;   // wait a bit before spin numbers
const long adjust_interval = 200; // delay between consecutive number increnents
const long bounce_delay = 20;     // contact bounce compensation
const int hrs_btn = A0;           // put hour adjusting button on A0 lane
const int min_btn = A1;           // put minute adjusting button on A1 lane
bool btn_pushed = false;          // is button pushed?
unsigned long currentPushTimer;
unsigned long previousPushTimer = 0;
uint8_t minutes;
uint8_t hours;

/* dot blinking stuff */
unsigned long currentMillis;
unsigned long previousMillis = 0;
const long interval = 500;
bool dot = true;

/* time inaccuracy compensation flag */
uint8_t compflag = 0;
const uint8_t timeSkew = 6; // assume that clock runs faster than should

/* ambient light compensation aka night mode */
const int photoPin = A2;

void setup()
{
	// setup display
	byte hardwareConfig = COMMON_ANODE;
	byte numDigits = 4;
	byte digitPins[] = {9, 10, 11, 12};
	byte segmentPins[] = {2, 3, 4, 5, 6, 7, 8, 13};
	bool resistorsOnSegments = true; // 8 resistors, 330 Ohms each
        /* updateWithDelays defaults to false and it is recommended value,
	 * but i was unable to make my display to change brightness with
	 * recommended value, so i have to use updateWithDelays=true,
	 * in this case brightness gets changed.
	 */
	bool updateWithDelays = true;   // Default. Recommended

	/* without it there is visual bug at 0 o'clock, and in current version
	 * of SevSeg' setChars() does not dots at all */
	bool leadingZeros = false;

	Display.begin(hardwareConfig, numDigits, digitPins, segmentPins,
                      resistorsOnSegments, updateWithDelays, leadingZeros);
	Display.setBrightness(100);

	// setup clock
	clock.begin();

	// if rtc returns incorrect time, reset it to some default value
	clock.getTime();

	if ((clock.hour > 23) || (clock.minute > 59)) {
		clock.fillByYMD(2019, 2, 23); // 23 Feb 2019
		clock.fillByHMS(15, 52, 30);  // 15:52:30"
		clock.fillDayOfWeek(SAT);     // Saturday
		clock.setTime();              // put date to rtc
	}

	// setup control buttons
	pinMode(hrs_btn, INPUT_PULLUP);
	pinMode(min_btn, INPUT_PULLUP);

	// setup brigtness sensor
	pinMode(photoPin, INPUT);
}

void loop()
{
	currentMillis = millis();
	currentPushTimer = currentMillis;
	char str[4];
	float d;
	unsigned int ambLight = analogRead(photoPin);

	clock.getTime();

	// push button magic
	if ((!btn_pushed) and
            ((digitalRead(hrs_btn) == LOW) or (digitalRead(min_btn) == LOW))) {
		if (currentPushTimer - previousPushTimer >= initial_delay) {
			previousPushTimer = currentPushTimer;
			btn_pushed = true;
		}
	}

	if (btn_pushed and
            (digitalRead(hrs_btn) != LOW) and (digitalRead(min_btn) != LOW)) {
		// compensate possible contact bounce with delay
		if (currentPushTimer - previousPushTimer >= bounce_delay) {
			btn_pushed = false;
		}
	}

	if (btn_pushed) {
		if (currentPushTimer - previousPushTimer >= adjust_interval) {
			previousPushTimer = currentPushTimer;

			if (digitalRead(hrs_btn) == LOW) {
				hours = clock.hour + 1;
				(hours > 23) ? hours = 0 : hours;
				clock.fillByHMS(hours, clock.minute, 0);
				clock.setTime();
			}

			if (digitalRead(min_btn) == LOW) {
				minutes = clock.minute + 1;
				(minutes > 59) ? minutes = 0 : minutes;
				clock.fillByHMS(clock.hour, minutes, 0);
				clock.setTime();
			}
		}
	}

	if (currentMillis - previousMillis >= interval) {
		previousMillis = currentMillis;

		if (dot)
			dot = false;
		else
			dot = true;
	}

	/*
	 * Let's implement time compenstion for individual rtc module time
	 * charachteristics. In in my case quartz resonator as inaccurate as
	 * +/- about 5-8 seconds per 24 hours, maybe its require more EMI
	 * shielding?
	 */

	if ((clock.hour == 21) and (clock.minute == 21) and
            (clock.second == 21) and (compflag == 0)) {
		clock.fillByHMS(clock.hour, clock.minute, (clock.second - timeSkew));
		clock.setTime();
		compflag = 1;
	}

	if ((clock.hour == 21) and (clock.minute == 21) and
            (clock.second == 23) and (compflag == 1)) {
		compflag = 0;
	}

	// make blinking dot
	if (clock.hour > 0) {
		if (dot) {
			Display.setNumber((clock.hour * 100 + clock.minute), 2);
		} else {
			Display.setNumber((clock.hour * 100 + clock.minute));
		}
	} else {
		/* 0 o'clock is an exception, we don't want to see "00.00", we
		   want see "0.00" or "0 00", so we have to use this "hack" */
		if (dot) {
			d = float(clock.minute) / 100;
			Display.setNumber(d, 2);
		} else {
			sprintf(str, "%2d%02d", clock.hour, clock.minute);
			Display.setChars(str);
		}
	}

	/* ambient light compensation
	 * ambLight can be in range of 0..1023, if it 800, it has point to use fullbright
	 */
	if (ambLight >= 940) {
		Display.setBrightness(100);
	} else if ((ambLight < 900) and (ambLight >= 840)) {
		Display.setBrightness(95);
	} else if ((ambLight < 800) and (ambLight >= 735)) {
		Display.setBrightness(70);
	} else if ((ambLight < 700) and (ambLight >= 635)) {
		Display.setBrightness(25);
	} else if ((ambLight < 600) and (ambLight >= 530)) {
		Display.setBrightness(15);
	} else if ((ambLight < 500) and (ambLight >= 430)) {
		Display.setBrightness(12);
	} else if ((ambLight < 400) and (ambLight >= 325)) {
		Display.setBrightness(10);
	} else if ((ambLight < 300) and (ambLight >= 220)) {
		Display.setBrightness(8);
	} else if ((ambLight < 200) and (ambLight >= 110)) {
		Display.setBrightness(7);
	} else if (ambLight < 100) {
		Display.setBrightness(6);
	}

	Display.refreshDisplay();
}

/* vim: set filetype=cpp: */