Initial commit

2021-07-29 03:23:25 +03:00
commit 1e0181a294
24 changed files with 2363 additions and 0 deletions
--- a/bin/aleesa-weba
+++ b/bin/aleesa-weba
@@ -0,0 +1,194 @@
+#!/usr/bin/perl
+
+use 5.018;
+use strict;
+use warnings;
+use utf8;
+use open qw (:std :utf8);
+use English qw ( -no_match_vars );
+
+use version; our $VERSION = qw (1.0);
+
+my $workdir;
+
+# before we run, change working dir
+BEGIN {
+	use Cwd qw (chdir abs_path);
+	my @CWD = split /\//xms, abs_path ($PROGRAM_NAME);
+
+	if ($#CWD > 1) {
+		$#CWD = $#CWD - 2;
+	}
+
+	$workdir = join '/', @CWD;
+	chdir $workdir;
+}
+
+use lib ("$workdir/lib", "$workdir/vendor_perl", "$workdir/vendor_perl/lib/perl5");
+no Cwd;
+use Cwd::utf8 qw (chdir abs_path);
+use File::Basename qw (basename dirname);
+use File::Path qw (make_path);
+use Log::Any qw ($log);
+use Log::Any::Adapter;
+use Log::Any::For::Std;
+use POSIX qw (setgid setuid setsid);
+use Conf qw (LoadConf);
+use WebApp qw (RunWebApp);
+
+sub daemonize;
+sub __fork;
+sub __signal_handler;
+
+local $OUTPUT_AUTOFLUSH = 1;
+my $runAsUid = $UID;
+
+my $piddir = '/var/run/' . basename (abs_path ($PROGRAM_NAME));
+my $C = LoadConf ();
+my $loglevel = $C->{'loglevel'} // 'notice';
+my $logfile;
+
+if (defined $C->{'log'}) {
+	$logfile = $C->{'log'};
+} elsif (defined $C->{'debug_log'}) {
+	$logfile = $C->{'debug_log'};
+}
+
+# if we run under root, create pid dir and set correct owner for it, same for debug log if it is defined
+if ($UID == 0) {
+	my $user = $C->{user};
+
+	unless (defined $user) {
+		die "Unable to run as root, please define unprivileged user in config.json\n";
+	}
+
+	my ($uid, $gid) = (getpwnam $user)[2,3];
+
+	unless (-d $piddir) {
+		make_path (
+			$piddir, {
+				uid   => $uid,
+				group => $gid
+			}
+		);
+	}
+
+	if (defined $logfile) {
+		my $logdir = dirname $logfile;
+
+		unless (-d $logdir) {
+			make_path (
+					$logdir, {
+							uid   => $uid,
+							group => $gid
+					}
+			) or die "Unable to create $logdir: $OS_ERROR\n";
+		}
+	}
+
+# drop privs
+	setgid ($gid) or die "Unable to switch to group of $user($OS_ERROR)\n";
+	setuid ($uid) or die "Unable to switch to account $user($OS_ERROR)\n";
+} else {
+	$piddir = $workdir;
+}
+
+if (defined $logfile) {
+	Log::Any::Adapter->set ('File', $logfile, log_level => $loglevel);
+
+	# Some annoying CHI logging events come with category set to CHI::Driver and log_level set to debug.
+	# Until we use start using Log::Any native features and set whole loglevel accordingly, lets lower
+	# verbosity paticulary for CHI.
+	Log::Any::Adapter->set (
+		{
+			category => 'CHI::Driver'
+		},
+		'File',
+		$logfile,
+		log_level => 'warn'
+	);
+} else {
+	Log::Any::Adapter->set ('File', '/dev/null');
+}
+
+# double fork attach to /dev/null all stdio and go background
+#daemonize ();
+
+# write pidfile
+my $apath = abs_path $PROGRAM_NAME;
+
+unless (defined $apath) {
+	$log->fatal ("[FATAL] Unable to get abs_path: $OS_ERROR\n");
+	exit 1;
+};
+
+# write pidfile
+my $pidfile = sprintf '%s/%s.pid', $piddir, basename $apath;
+$log->info ("[INFO] Creating pidfile at $pidfile");
+
+open my $MYPID, '>', $pidfile or do {
+	$log->fatal ("[FATAL] Error opening $pidfile: $OS_ERROR");
+	exit 1;
+};
+
+print {$MYPID} $PID or do {
+	$log->fatal ("[FATAL] Error writing to $pidfile: $OS_ERROR");
+	exit 1;
+};
+
+close $MYPID;                                        ## no critic (InputOutput::RequireCheckedSyscalls
+
+local $SIG{INT}  = \&__signal_handler;
+local $SIG{TERM} = \&__signal_handler;
+
+# set correct proctitle
+$PROGRAM_NAME = abs_path $PROGRAM_NAME;              ## no critic (Variables::RequireLocalizedPunctuationVars)
+
+# run bot, at last
+RunWebApp ();
+
+if (-f $pidfile) {
+	unlink $pidfile;
+}
+
+exit 0;
+
+sub daemonize {
+	__fork ();
+	POSIX::setsid ();
+	open STDIN, '<', '/dev/null';                    ## no critic (InputOutput::RequireCheckedSyscalls, InputOutput::RequireCheckedOpen)
+	# we handle STDOUT && STDERR via Log::Any::For::Std, so do not close them explicitly
+	#open STDOUT, '>', '/dev/null';                   ## no critic (InputOutput::RequireCheckedSyscalls, InputOutput::RequireCheckedOpen)
+	#open STDERR, '>', '/dev/null';                   ## no critic (InputOutput::RequireCheckedSyscalls, InputOutput::RequireCheckedOpen)
+	__fork ();
+	umask 0;
+	return;
+}
+
+sub __fork {
+	my $pid = fork;
+
+	unless (defined $pid) {
+		$log->fatal ("[FATAL] Can't fork: $OS_ERROR");
+		exit 1;
+	}
+
+	if ($pid != 0) {
+		exit;
+	}
+
+	return;
+}
+
+sub __signal_handler {
+	$log->info ("[INFO] Caught a signal $OS_ERROR");
+
+	if (-f $pidfile) {
+		unlink $pidfile;
+	}
+
+	exit 0;
+}
+
+__END__
+# vim: set ft=perl noet ai ts=4 sw=4 sts=4:
--- a/bin/test-pub.pl
+++ b/bin/test-pub.pl
@@ -0,0 +1,49 @@
+#!/usr/bin/perl
+
+use 5.018;
+use strict;
+use warnings;
+use utf8;
+use open qw (:std :utf8);
+use English qw ( -no_match_vars );
+use version; our $VERSION = qw (1.0);
+
+my $workdir;
+
+# before we run, change working dir
+BEGIN {
+	use Cwd qw (chdir abs_path);
+	my @CWD = split /\//xms, abs_path ($PROGRAM_NAME);
+	if ($#CWD > 1) { $#CWD = $#CWD - 2; }
+	$workdir = join '/', @CWD;
+	chdir $workdir;
+}
+
+use lib ("$workdir/lib", "$workdir/vendor_perl", "$workdir/vendor_perl/lib/perl5");
+use Mojo::Redis;
+use Conf qw (LoadConf);
+
+my $c = LoadConf ();
+
+my $redis = Mojo::Redis->new (
+	sprintf 'redis://%s:%s/1', $c->{server}, $c->{port}
+);
+
+my $pubsub = $redis->pubsub;
+my @messages = ('!cat', '!fox', '!drink', '!monkeyuser', '!xkcd');
+
+while (1) {
+	$pubsub->json ('webapp:TEST')->notify (
+		'webapp:TEST' => {
+			from    => 'test-pub.pl',
+			userid  => 'test_user',
+			chatid  => '#test_chat',
+			plugin  => 'dummy_plugin',
+			message => $messages [int (rand ($#messages + 1))]
+		}
+	);
+
+	sleep 3;
+}
+
+exit 0;
--- a/bin/test-sub.pl
+++ b/bin/test-sub.pl
@@ -0,0 +1,53 @@
+#!/usr/bin/perl
+
+use 5.018;
+use strict;
+use warnings;
+use utf8;
+use open qw (:std :utf8);
+use English qw ( -no_match_vars );
+use version; our $VERSION = qw (1.0);
+
+my $workdir;
+
+# before we run, change working dir
+BEGIN {
+	use Cwd qw (chdir abs_path);
+	my @CWD = split /\//xms, abs_path ($PROGRAM_NAME);
+	if ($#CWD > 1) { $#CWD = $#CWD - 2; }
+	$workdir = join '/', @CWD;
+	chdir $workdir;
+}
+
+use lib ("$workdir/lib", "$workdir/vendor_perl", "$workdir/vendor_perl/lib/perl5");
+use Carp qw (carp);
+use Mojo::Redis;
+use Data::Dumper;
+
+use Conf qw (LoadConf);
+
+my $c = LoadConf ();
+
+my $redis = Mojo::Redis->new (
+	sprintf 'redis://%s:%s/1', $c->{server}, $c->{port}
+);
+
+my $pubsub = $redis->pubsub;
+
+$pubsub->json('webapp:TEST')->listen (
+	'webapp:TEST' => sub {
+		my $self = shift;
+		my $message = shift;
+		carp Dumper ($message);
+	 }
+);
+
+$pubsub->json('broadcast')->listen (
+	'broadcast' => sub {
+		my $self = shift;
+		my $message = shift;
+		carp Dumper ($message);
+	}
+);
+
+Mojo::IOLoop->start unless Mojo::IOLoop->is_running;
--- a/bin/test.pl
+++ b/bin/test.pl
@@ -0,0 +1,88 @@
+#!/usr/bin/perl
+
+use 5.018;
+use strict;
+use warnings;
+use utf8;
+use open qw (:std :utf8);
+use English qw ( -no_match_vars );
+use version; our $VERSION = qw (1.0);
+
+my $workdir;
+
+# before we run, change working dir
+BEGIN {
+	use Cwd qw (chdir abs_path);
+	my @CWD = split /\//xms, abs_path ($PROGRAM_NAME);
+	if ($#CWD > 1) { $#CWD = $#CWD - 2; }
+	$workdir = join '/', @CWD;
+	chdir $workdir;
+}
+
+use lib ("$workdir/lib", "$workdir/vendor_perl", "$workdir/vendor_perl/lib/perl5");
+use Carp qw (carp);
+use Mojo::Redis;
+use Data::Dumper;
+
+use Conf qw (LoadConf);
+my @messages = ('!cat', '!fox', '!drink', '!monkeyuser', '!xkcd');
+my $c = LoadConf ();
+
+my $redis = Mojo::Redis->new (
+	sprintf 'redis://%s:%s/1', $c->{server}, $c->{port}
+);
+
+my $pubsub = $redis->pubsub;
+
+# Добавим коллбэк на приход события в test.
+$pubsub->json ('test')->listen (
+	'test' => sub { 
+#		my $self = shift;
+#		my $message = shift;
+		carp Dumper (@_);
+	 }
+);
+
+# Добавим коллбэк на приход события в broadcast.
+$pubsub->json ('broadcast')->listen (
+	'broadcast' => sub {
+#		my $self = shift;
+#		my $message = shift;
+		carp Dumper (@_);
+	}
+);
+
+# Попробуем потыкать в наш сервер приложений разными сообщениями.
+# Этот коллбэк запускается по таймеру, раз в 3 секунды.
+Mojo::IOLoop->recurring (
+	3 => sub {
+		my $channel = 'test';
+		if (int (rand (2))) { $channel = 'broadcast' }
+
+		$pubsub->json ('webapp:test')->notify (
+			'webapp:test' => {
+				from    => $channel, # <- отвечаем в этот pubsub-канал
+				userid  => 'test_user',
+				chatid  => '#test_chat',
+				plugin  => 'dummy_plugin',
+				message => $messages [int (rand ($#messages + 1))]
+			}
+		);
+	}
+);
+
+# поприветствуем наше тестируемое приложение, это необходимо чтобы оно подписалось на нас.
+$pubsub->json ('webapp:TEST')->notify (
+	'webapp:TEST' => {
+		from    => 'test', # <- отвечаем в этот pubsub-канал
+		userid  => 'test_user',
+		chatid  => '#test_chat',
+		plugin  => 'dummy_plugin',
+		message => 'Hello'
+	}
+);
+
+# Приветствовать test не нужно, так как он безо всякой эвристики подписан и на себя и на broadcast
+
+# Все нужные обработчики напиханы в ивент-луп, можно его запускать.
+Mojo::IOLoop->start unless Mojo::IOLoop->is_running;