Add migration scripts and doc.
When I move bot from perl-5.30.0 to perl-5.32.1 I encounter with BDB0091 DB_VERSION_MISMATCH error And it looks like I have to export essential data on older perl to some portable format and then import it on newer perl environment.
This commit is contained in:
eleksir
106
bin/cache_export.pl
Normal file
106
bin/cache_export.pl
Normal file
@@ -0,0 +1,106 @@
|
||||
#!/usr/bin/perl
|
||||
|
||||
use 5.018;
|
||||
use strict;
|
||||
use warnings;
|
||||
use utf8;
|
||||
use open qw (:std :utf8);
|
||||
use English qw ( -no_match_vars );
|
||||
use version; our $VERSION = qw (1.0);
|
||||
|
||||
my $workdir;
|
||||
|
||||
# before we run, change working dir
|
||||
BEGIN {
|
||||
use Cwd qw (chdir abs_path);
|
||||
my @CWD = split /\//xms, abs_path ($PROGRAM_NAME);
|
||||
if ($#CWD > 1) { $#CWD = $#CWD - 2; }
|
||||
$workdir = join '/', @CWD;
|
||||
chdir $workdir;
|
||||
}
|
||||
|
||||
use lib ("$workdir/lib", "$workdir/vendor_perl", "$workdir/vendor_perl/lib/perl5");
|
||||
use CHI;
|
||||
use CHI::Driver::BerkeleyDB;
|
||||
use File::Basename qw (dirname);
|
||||
use File::Path qw (make_path);
|
||||
use JSON::XS;
|
||||
use Encode;
|
||||
|
||||
use BotLib::Conf qw (LoadConf);
|
||||
|
||||
my $c = LoadConf ();
|
||||
my $cachedir = $c->{cachedir};
|
||||
my $datadir = dirname $cachedir;
|
||||
my $export = 0;
|
||||
my $exportInst = 0;
|
||||
|
||||
sub dumpCache {
|
||||
my $namespace = shift;
|
||||
my $cacheExportDir = sprintf '%s/cacheexport', $datadir;
|
||||
|
||||
unless (-d $cacheExportDir) {
|
||||
make_path ($cacheExportDir) || die "Unable to create $cacheExportDir: $OS_ERROR\n";
|
||||
}
|
||||
|
||||
my $filename = sprintf '%s/%s', $cacheExportDir, $exportInst;
|
||||
|
||||
my $cache = CHI->new (
|
||||
driver => 'BerkeleyDB',
|
||||
root_dir => $cachedir,
|
||||
namespace => $namespace
|
||||
);
|
||||
|
||||
my $j;
|
||||
my $writefile = 0;
|
||||
|
||||
foreach my $k ($cache->get_keys ()) {
|
||||
$k = decode ('UTF-8', $k);
|
||||
$j->{$k} = decode ('UTF-8', $cache->get ($k));
|
||||
$writefile = 1;
|
||||
}
|
||||
|
||||
if ($writefile) {
|
||||
say "Dumping $namespace"; ## no critic (InputOutput::RequireCheckedSyscalls)
|
||||
my $jsonencoder = JSON::XS->new->pretty ();
|
||||
open (my $FILE, '>', $filename) or die "Unable to dump cache namespace $namespace to $filename: $OS_ERROR\n";
|
||||
print $FILE $jsonencoder->encode ($j) or die "Unable to dump cache namespace $namespace to $filename: $OS_ERROR\n";;
|
||||
close $FILE; ## no critic (InputOutput::RequireCheckedSyscalls)
|
||||
my $EXPORTFD;
|
||||
|
||||
if ($export) {
|
||||
open ($EXPORTFD, '>>', "$cacheExportDir/exportfiles.txt") or die "Unable to open for appending $cacheExportDir/exportfiles.txt: $OS_ERROR\n";
|
||||
} else {
|
||||
open ($EXPORTFD, '>', "$cacheExportDir/exportfiles.txt") or die "Unable to create $cacheExportDir/exportfiles.txt: $OS_ERROR\n";
|
||||
$export = 1;
|
||||
}
|
||||
|
||||
printf ($EXPORTFD "%s,%s\n", $namespace, $filename) or die "Unable to write to $cacheExportDir/exportfiles.txt: $OS_ERROR\n";
|
||||
close $EXPORTFD; ## no critic (InputOutput::RequireCheckedSyscalls)
|
||||
$exportInst++;
|
||||
}
|
||||
|
||||
return;
|
||||
}
|
||||
|
||||
opendir (my $DIR, $cachedir) or die "Unable to open $cachedir: $OS_ERROR\n";
|
||||
|
||||
while (readdir $DIR) {
|
||||
if (/^BotLib\+3a\+3aAdmin_censor_(.+)\.db$/) {
|
||||
dumpCache ("BotLib::Admin_censor_$1");
|
||||
} elsif (/^BotLib\+3a\+3aAdmin_fortune.db$/) {
|
||||
dumpCache ('BotLib::Admin_fortune');
|
||||
} elsif (/BotLib\+3a\+3aAdmin_plugin_(.+)\.db$/) {
|
||||
dumpCache ("BotLib::Admin_plugin_$1");
|
||||
} elsif (/BotLib\+3a\+3aAdmin_(.+)\.db$/) {
|
||||
dumpCache ("BotLib::Admin_$1");
|
||||
} elsif (/^BotLib\+3a\+3aImage\+3a\+3aFlickr\.db$/) {
|
||||
dumpCache ('BotLib::Image::Flickr');
|
||||
} elsif (/^BotLib\+3a\+3aKarma_(.+)\.db$/) {
|
||||
dumpCache ("BotLib::Karma_$1");
|
||||
}
|
||||
}
|
||||
|
||||
closedir $DIR;
|
||||
exit 0;
|
||||
|
||||
86
bin/cache_import.pl
Normal file
86
bin/cache_import.pl
Normal file
@@ -0,0 +1,86 @@
|
||||
#!/usr/bin/perl
|
||||
|
||||
use 5.018;
|
||||
use strict;
|
||||
use warnings;
|
||||
use utf8;
|
||||
use open qw (:std :utf8);
|
||||
use English qw ( -no_match_vars );
|
||||
use version; our $VERSION = qw (1.0);
|
||||
|
||||
my $workdir;
|
||||
|
||||
# before we run, change working dir
|
||||
BEGIN {
|
||||
use Cwd qw (chdir abs_path);
|
||||
my @CWD = split /\//xms, abs_path ($PROGRAM_NAME);
|
||||
if ($#CWD > 1) { $#CWD = $#CWD - 2; }
|
||||
$workdir = join '/', @CWD;
|
||||
chdir $workdir;
|
||||
}
|
||||
|
||||
use lib ("$workdir/lib", "$workdir/vendor_perl", "$workdir/vendor_perl/lib/perl5");
|
||||
use CHI;
|
||||
use CHI::Driver::BerkeleyDB;
|
||||
use File::Basename qw (dirname);
|
||||
use File::Path qw (make_path);
|
||||
use JSON::XS;
|
||||
use Encode;
|
||||
|
||||
use BotLib::Conf qw (LoadConf);
|
||||
|
||||
my $c = LoadConf ();
|
||||
my $cachedir = $c->{cachedir};
|
||||
my $datadir = dirname $cachedir;
|
||||
my $export = 0;
|
||||
|
||||
sub createCache {
|
||||
my $namespace = shift;
|
||||
my $filename = shift;
|
||||
say "Creating $namespace from $filename"; ## no critic (InputOutput::RequireCheckedSyscalls)
|
||||
|
||||
my $cache = CHI->new (
|
||||
driver => 'BerkeleyDB',
|
||||
root_dir => $cachedir,
|
||||
namespace => $namespace
|
||||
);
|
||||
|
||||
open my $FH, '<', $filename or die "Unable to open $filename: $OS_ERROR\n";
|
||||
binmode $FH;
|
||||
my $len = (stat $filename) [7];
|
||||
my $json;
|
||||
use bytes;
|
||||
my $readlen = read $FH, $json, $len;
|
||||
no bytes;
|
||||
|
||||
unless ($readlen) {
|
||||
close $FH; ## no critic (InputOutput::RequireCheckedSyscalls
|
||||
die "Unable to read $filename: $OS_ERROR\n";
|
||||
}
|
||||
|
||||
if ($readlen != $len) {
|
||||
close $FH; ## no critic (InputOutput::RequireCheckedSyscalls
|
||||
die "File $filename is $len bytes on disk, but we read only $readlen bytes\n";
|
||||
}
|
||||
|
||||
close $FH; ## no critic (InputOutput::RequireCheckedSyscalls
|
||||
my $j = JSON::XS->new->utf8->relaxed;
|
||||
my $dump = $j->decode ($json);
|
||||
|
||||
foreach my $key (keys (%{$dump})) {
|
||||
$cache->set ($key, $dump->{$key}, 'never');
|
||||
}
|
||||
|
||||
return;
|
||||
}
|
||||
|
||||
open (my $FH, '<', "$datadir/cacheexport/exportfiles.txt") or die "Unable to open $datadir/cacheexport/exportfiles.txt: $OS_ERROR\n";
|
||||
|
||||
while (<$FH>) {
|
||||
chomp;
|
||||
my ($namespace, $filename) = split /\,/, $_, 2;
|
||||
createCache ($namespace, $filename);
|
||||
}
|
||||
|
||||
close $FH; ## no critic (InputOutput::RequireCheckedSyscalls)
|
||||
exit 0;
|
||||
Reference in New Issue
Block a user